Enhancing Kyosho model car with LED lights: Design phase

A led module to increase the user feedback for RC models

Introduction

RC models such as cars, planes, and boats can be used for enhancing user driving capabilties but they lack of user feedback as regards the model status. Looking down on the remote controller is not possible because the visual inspection of the model can be lost as it crucial in racing. In other cases, the instructor should see the trainee input and grab the controller before it is too late or to suggest other ways to control the car, i.e. when to brake and how much throttle should be applied. So, there is a need to have a feedback of the user input - especially the throttle - while looking at it.

RC racing models are interesting for applying our method due to their efficiency as well as their durability. The car Kyosho MP10 TKI2 and similar models offer an excellent introduction into mechanical engineering due to their small scale factor 1/8, methanol-oil 2-stroke engine generating 2-3hp at 3.5cc, and racing character. It can reach up to 100km/h final speed and it has durable forged parts. This Kyosho model as shown in Figure 1 was selected as our testing platform.

Figure 1: Assembly of Kyosho MP10 TKI2 that was the selected platform for the development.

LED stripes are quite popular and advanced as they offer a bright interface for the user at a reasonable cost. The target is to place a LED strip over the Kyosho model that indicate how much throttle or brake is pressed. In other words, it will be a live feedback for training future drivers. The design should be durable, low power consumption, aerodynamic, and lightweight so that it does not affect the efficiency of the car. The methodology followed is analyzed in the following section.

Methodology

Led strip WS2813c was selected due it its small power consumption. Each RGB channel consumes at full brightness 5mA. We are going to use 40 LEDs with Green or Red colors. The maximum amperage used was measured as 0.85amps. It should be powered at 5V.

It will turn on LED lights gradually based on the Channel 2 of the radio emitter, namely gas press. Led strip WS2813C was selected due it its small power consumption.

The Led stripe is controlled by an Arduino. The Arduino Uno was used in the research phase, while Arduino nano v3 was used in the production due its small scale factor. Its power consumption is measured at 0.2amps (Todo: conditions are missing here)

A C program for Arduino is written that progressively turns on red color, turns it off also progressively, and does the same thing with green leds.

Power transformation

LM2596 DC-DC Step-down Power Supply Module 3A Adjustable Step-down Module LM2596S Voltage Regulator 24V 12V 5V 3V For arduino

Future work

The next phase will a) connect the remote control with Arduino, and b) a voltage regulator will be designed so that the 8.2V LiPo battery can feed the led stripe that works for voltage under 5.5V. These will conclude the research phase, and next the installation phase will begin.

THE CODE v2

Use Arduino Sketch to install to NANO

// Turn on strip WS2813 with 144 LED lights 
//   according to channel 2 signal 
//      of flysky FS-GR3E receiver
//
// Controller Arduino Uno R3
// For connection diagram see 
//    dimitriosververidis.blogspot.com
//
// Dimitrios Ververidis v1: 14/11/2025, first working version for UNO
//                      v2: 23/11/2025, intensifier light. Fine tune for NANO.
// MIT License
// Free but use at your own risk

// Library for strip
#include <Adafruit_NeoPixel.h>

// Data led for strip (use a 330 ohm R)
#define LED_PIN    6

// Number of leds on the strip
#define NUM_LEDS   144

// Define led strip
Adafruit_NeoPixel strip(NUM_LEDS, LED_PIN, NEO_GRB + NEO_KHZ800);

// Signal received at arduino slot 2 as pwm pulses (not analog) 
int ch2Pin = 2;  // CH2 connected to D2

// FS-GR3E Neutral 
#define PULSE_NEUTRAL 1500
// #define PULSE_FULL_MAX 1700
// #define PULSE_FULL_BRAKE 1300

// Initialize
void setup() 
{
  // Listening frequency
  Serial.begin(9600);

  // Pin to hear signal from FlySky
  pinMode(ch2Pin, INPUT);

  // Initialize Strip  
  strip.begin();
}

// Main
void loop() 
{
  // ----- Measure the HIGH pulse width (in microseconds) ------------------
  int pulse = pulseIn(ch2Pin, HIGH, 25000) - PULSE_NEUTRAL;  // 25 ms timeout

  // Console output
  // Serial.print("CH2 pulse width: ");
  // Serial.print(pulse);
  // Serial.println(" us");
  delay(50);

  // ------------------ LED --------------------------

  // Turn all LEDs off before visualizing next step
  for (int i = 0; i < NUM_LEDS; ++i) 
  {
    strip.setPixelColor(i, 0); // Off all leds
  }

  // Green/Yellow for Throttle
  if ( pulse > 3 )
  {
      // Light up LEDs one by one starting from Led 72 (center)
      //                     ~280 / 4 ~= 70
      for ( int i = 0; i < abs( pulse / 4 ); ++i ) 
      {   
        // green or yellow                     R         G  B
        uint32_t col =  i < 55 ? strip.Color(   0, (i+1)*4, 0 ): // Green
                                 strip.Color( 200,      80, 0 ); // Yellow

        strip.setPixelColor( 72 + i, col ); // left
        strip.setPixelColor( 72 - i, col ); // right
      }
  }
  // Red for Brake
  else if ( pulse < - 5 )
  {
      // Light up LEDs one by one
      for ( int i = 0; i < abs( pulse ) / 2; ++i ) 
      {        
        strip.setPixelColor( 72 + i, strip.Color( i*3, 0, 0 ) ); // Red left
        strip.setPixelColor( 72 - i, strip.Color( i*3, 0, 0 ) ); // Red right
      }
  }
   
  // Invalidate
  strip.show();
}

LM2596 HW-411 was used for step down 8.2v to 6v for 2A for servos. At a first glance using dupont connectors we saw an increase in temperature at 6V OUT+ when ambient is 13 Celsius the dupont can reach 30 Celcius (thermal video 1 below). Upon replacing the dupont with a typical cable that it is used in PSU for PCs, temperature stayed 10 degrees lower (thermal video 2 below).

Appendix

Components

LED : WS2813C with 144 lights (aliexpress, 15euros)
Radio: Flysky FS-GR3E receiver and GT3C transmitter (hobbyland.gr, 80 euros)
Controller: Arduino UNO R3 (skroutz.gr, 8 euros). Second phase NANO R3 (7 euros).
Battery: A 2 cell LiPo 8.2v at 2700mAh.
LM2895: Two step down buck converters as modules for reducing 8.2v to 5v.
Capacitor: To be filled C for stabilizing led stripe current.

Tools: